|
|
楼主 |
发表于 2023-9-15 08:16:05
|
显示全部楼层
1. 创建配置文件（COM 文件）
配置文件的内容
在 UTF8 编辑器中为两个对话框创建配置文件 diag.com 。
；登入软键开始标记
//S(START)
；纯文本登入软键
HS7=("START")
；登入软键，带和语言相关的文本和 png
;HS7=([$80792,"\\sk_ok.png"])
；PRESS 方法
PRESS(HS7)
；功能 LM 或者 LS
LM("MASK1")
；带 com 文件说明的 LM
LM("MASK1","TEST.COM")
END_PRESS
；登入软键结束标记
//END
；带标题和图像的对话框 1 的定义
//M(MASK1/"Display R parameter and Channel MD"/"mz961_01.png")
；变量定义
DEF VAR1 = (R2///,"R parameter 0"///"$R[0]"/200,50,150/400,50,100,)
；带帮助图形
DEF VAR2 = (R2///,"R parameter 1"//"mz961_02.png"/"$R[1]"/200,70,150/400,70,100)
；带在线帮助
DEF ACHS_NAM1 = (S///"Press i for Help","Geometry axis[0]"////
200,100,150/400,100,100//"sinumerik_md_1.html","20060[0]")
；带在线帮助
DEF ACHS_NAM2 = (S///"Press i for Help","Geometry axis[1]"////
200,120,150/400,120,100//"sinumerik_md_1.html","20060[1]")
DEF ACHS_NAM3 = (S///,"Geometry axis[2]"////200,140,150/400,140,100)
；转换栏和单位转换栏的定义
DEF VAR_TGL = (S/* "Hello", "Run", "MyScreens"/"Run"/,"Toggle box"////10,230,100/120,230,100/,,6)
DEF VAR_TGB = (S/* "Hello", "Run", "MyScreens"/"Run"/,"List box"/
dt4///250,230,100/370,230,100,60/,,"#0602ee")
; BC, FC, BC_ST, FC_ST, BC_GT, FC_GT, BC_UT, FC_UT, SC1, SC2
DEF VarEdit = (R///,"Unit Toggle",,,"Feedrate"///"$R[11]"/5,300,100/120,300,100///"VarTgl"),
VarTgl = (S/*0="mm",1="inch"/0//WR2////220,300,40)
；对话框中的软键定义
HS1=("")
HS2=("")
HS3=("")
HS4=("")
HS5=("")
HS6=("")
HS7=("")
HS8=("")
VS1=("")
VS2=("")
VS3=("")
VS4=("")
VS5=("")
VS6=("")
VS7=("next Mask")
VS8=("EXIT")
；LOAD 块定义
LOAD
；通过 RNP 读取值
ACHS_NAM1 = RNP("$MC_AXCONF_GEOAX_NAME_TAB[0]")
ACHS_NAM2 = RNP("$MC_AXCONF_GEOAX_NAME_TAB[1]")
ACHS_NAM3 = RNP("$MC_AXCONF_GEOAX_NAME_TAB[2]")
；对话框行输出
DLGL("Value R2: = " << RNP("$R[2]"))
；通过 WNP 写入值
WNP("$R[3]",VAR0)
；垂直分割线
V_SEPARATOR(360,1,6,1)
；水平分割线
H_SEPARATOR(220,1,7,1)
END_LOAD
；PRESS 方法
PRESS(VS7)
；载入其他对话框
LM("MASK2")
；PRESS 方法的结束标记
END_PRESS
；PRESS 方法
PRESS(VS8)
；退出对话框
EXIT
；PRESS 方法的结束标记
END_PRESS
；对话框 1 的结束标记
//END
；带标题和图像的对话框 2 的定义
//M(MASK2/"Position WCS MCS"/"mz961_01.png")
；变量定义
DEF TEXT1 = (I///,"WCS"/WR0,fs2///230,30,120/,,1)
DEF VAR1 = (R3///,"1. Axis $AA_IW[AX1]"/WR1//"$AA_IW[AX1]"/230,70,150/400,70,100)
DEF VAR2 = (R3///,"2. Axis $AA_IW[AX2]"/WR1//"$AA_IW[AX2]"/230,90,150/400,90,100)
DEF TEXT2 = (I///,"MCS"/WR0,fs2///230,120,120/,,1)
DEF VAR3 = (R2///,"1. Axis $AA_IM[AX1]"/WR1//"$AA_IM[AX1]"/230,160,150/400,160,100)
DEF VAR4 = (R2///,"2. Axis $AA_IM[AX2]"/WR1//"$AA_IM[AX2]"/230,180,150/400,180,100)
DEF VAR5 = (R3///,"$P_UIFR G54 AX1"///"$P_UIFR[1,AX1,TR]"/230,200,150/400,200,100)
；进度条的定义
DEF PROGGY0 = (R/0,150//,"Progress bar Operate style"/DT2,DO0//"$R[10]"/5,240,190/5,260,150/6,10)
DEF PROGGY4 = (R/0,150,50,100/120/,"Progress bar with color change"/DT1,DO0//"$R[10]"/
260,240,190/260,260,150/3,4,,,9,7)
；变量定义
DEF PROGVAL = (R/0,150//,"Value to change Progress bar 0 - 150"///"$R[10]"/5,300,230/260,300,100)
；对话框中的软键定义
HS1=("")
HS2=("")
HS3=("")
HS4=("")
HS5=("")
HS6=("")
HS7=("")
HS8=("")
VS1=("")
VS2=("")
VS3=("")
VS4=("")
VS5=("")
VS6=("")
VS7=("Back to Mask")
VS8=("EXIT")
; Load 方法
LOAD
H_SEPARATOR(230,1,7,1)
END_LOAD
；更改方法
CHANGE(VAR5)
；PI_START 功能
PI_START("/NC,201,_N_SETUFR")
；更改方法的结束标记
END_CHANGE
；PRESS 方法
PRESS(RECALL)
；返回主调对话框
LM("MASK1")
；PRESS 方法的结束标记
END_PRESS
；PRESS 方法
PRESS(VS7)
；返回主调对话框
LM("MASK1")
；PRESS 方法的结束标记
END_PRESS
；PRESS 方法
PRESS(VS8)
；退出对话框，返回到标准应用程序
EXIT
；PRESS 方法的结束标记
END_PRESS
；对话框的结束标记
//END |
|
发表于 2023-9-15 08:05:20
